# Contributor: Dirk Stolle

_realname=File-ShareDir
pkgname=perl-${_realname}
pkgver=1.118
pkgrel=1
pkgdesc="Locate per-dist and per-module shared files"
arch=('i686' 'x86_64')
license=('spdx:GPL-1.0-only' 'spdx:Artistic-1.0-Perl')
url='https://metacpan.org/dist/File-ShareDir'
msys2_repository_url='https://github.com/perl5-utils/File-ShareDir'
msys2_changelog_url='https://github.com/perl5-utils/File-ShareDir/blob/master/Changes'
msys2_references=(
  'archlinux: perl-file-sharedir'
  'cygwin: perl-File-ShareDir'
  'purl: pkg:cpan/REHSACK/File-ShareDir'
)
groups=('perl-modules')
depends=('perl' 'perl-Class-Inspector')
makedepends=('perl-devel' 'make')
checkdepends=('perl-Test-Pod')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/R/RE/REHSACK/${_realname}-${pkgver}.tar.gz")
sha256sums=('3bb2a20ba35df958dc0a4f2306fc05d903d8b8c4de3c8beefce17739d281c958')

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make test
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make install DESTDIR="${pkgdir}"
}
