# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=flit
PYTHON_COMPAT=( python3_{11..14} )

inherit distutils-r1

DESCRIPTION="Python SNMP library"
HOMEPAGE="
	https://pypi.org/project/pysnmp/
	https://github.com/lextudio/pysnmp/
"
SRC_URI="
	https://github.com/lextudio/pysnmp/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~sparc ~x86"
PROPERTIES="test_network"
RESTRICT="test"

RDEPEND="
	>=dev-python/cryptography-43.0.1[${PYTHON_USEDEP}]
	>=dev-python/pyasn1-0.6.3[${PYTHON_USEDEP}]
	>=dev-python/pysmi-2.0.0[${PYTHON_USEDEP}]
"

EPYTEST_PLUGINS=( pytest-{asyncio,rerunfailures} )
# flaky because of timeouts
EPYTEST_RERUNFAILURES=5
distutils_enable_tests pytest
# TODO
# distutils_enable_sphinx docs/source dev-python/furo dev-python/sphinx-copybutton dev-python/sphinx-sitemap

python_test() {
	# see .github/workflows/build-test.yml
	mibdump --generate-mib-texts NET-SNMP-EXAMPLES-MIB || die
	mibdump --generate-mib-texts IF-MIB || die
	mibdump --generate-mib-texts LEXTUDIO-TEST-MIB || die
	mibdump --generate-mib-texts CISCO-ENHANCED-IPSEC-FLOW-MIB.py || die
	mibdump --generate-mib-texts TCP-MIB || die

	epytest
}